@echo off
title 简易U盘病毒清理系统1.25
cls
color 1f
echo ************************************************************************
echo * *
echo * 欢迎使用梦之光芒简易U盘病毒清理系统1.25 *
echo * *
echo * 本程序为免费软件,任何个人可随意使用,但不得用于商业用途 *
echo * *
echo * 本程序允许随意传播,但任何对本程序更改版权后的传播均为侵权 *
echo * *
echo * 由于本程序以验证文件名的形式进行病毒的识别,所以会不定期升级 *
echo * *
echo * 获得程序升级请到作者个人主页:
http://hi.baidu.com/monyer *
echo * *
echo * OICQ:2598841 Email:
monyer@126.com *
echo * *
echo * 作者:Monyer(梦之光芒)于2006年12月13日 *
echo * *
echo ************************************************************************
pause
cls
echo 正在检测您系统中的可移动设备
setlocal enabledelayedexpansion
for /f "skip=1 tokens=1,2 delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (
set genre=%%i
set genre=!genre:~-2!
for %%a in (!genre!) do (
fsutil fsinfo drivetype %%a | findstr "移动" >nul 2>nul && if /i not "%%a"=="A:" (
set drive=%%a
echo.
echo 找到可移动存储设备, 盘符为%%a ,请确定盘符正确性。若不正确请立即退出本程序。
echo.
echo.
echo 正在处理U盘隐藏文件...
echo.
!drive!
attrib -r -h -s -a *.* >nul 2>nul
call :go
)
)
)
cls
echo 检测完毕!没有检测到U盘存在!请点击任意键推出!
pause
exit
:go
echo.
echo U盘病毒清理选项:
echo ┌─────────────────────────────────────┐
echo │[1]普通杀毒 (仅删除与内置列表文件名相同的可执行文件) │
echo │[2]安全进入 (不杀毒,但以更安全的模式进入U盘) │
echo │[3]终极杀毒 (删除U盘上所有可能被感染病毒的可执行文件,有一定危险性!) │
echo │[4]U盘免疫 (选择此选项,以后即使你的U盘有病毒,也不会自动运行了) │
echo │[5]解除免疫 (解除本系统对U盘所作的免疫,仅对本系统的免疫有效) │
echo │[6]格式化U盘 (将你的U盘清空。请确保U盘上没有重要的文件或已经做好备份!) │
echo │[7]退出 │
echo └─────────────────────────────────────┘
set /p choice=请选择输入数字(1~7):
if /i "%choice%"=="1" goto putong
if /i "%choice%"=="2" goto nokill
if /i "%choice%"=="3" goto zhongji
if /i "%choice%"=="4" goto mianyi
if /i "%choice%"=="5" goto jiechu
if /i "%choice%"=="6" goto geshi
if /i "%choice%"=="7" goto theEnd
goto go
:putong
cls
title 简易U盘病毒清理系统——普通杀毒
echo.
echo 开始进行普通病毒检测及清除...
echo.
for %%b in (AdobeR.exe AdobeR.exe.log autorun.exe bittorrent.exe copy.exe ctfmon.exe desktop.exe desktop2.exe desktop.ini doc.exe folder.exe ghost.bat host.exe msinfmgr.exe msvcr71.dll nethood.htm nethood.html RavMonE.exe RavMonLog rose.exe setup.pif SHE.exe svchost.exe sxs.exe sys.com SYSTEM.VER tel.xls.exe toy.exe wincfgs.exe window.exe win.exe win32.exe win33.exe) do if exist %%b del /f/s/q/a %%b
if exist RECYCLER Rmdir /s/q RECYCLER
goto :nokill
:zhongji
cls
title 简易U盘病毒清理系统——终极杀毒
echo.
echo 该方式会删除您U盘中的所有可执行文件,有极强的危险性,仅用于插入型病毒。如果你认为你U盘上的所有文件都已经被感染了,请选择杀毒,否则请选择不杀毒
echo.
set /p choice=请选择(1 =杀毒 2 =不杀毒):
if /i "%choice%"=="1" goto zhongji1
if /i "%choice%"=="2" goto go
goto zhongji
:zhongji1
cls
echo.
echo 开始进行终极杀毒
echo.
echo 开始扫描危险文件并执行删除...
for %%b in (*.app *.bat *.cmd *.com *.cpl *.dll *.exe *.hta *.inf *.jse *.msi *.msp *.mst *.pif *.prf *.prg *.reg *.scf *.scr *.sct *.shb *.shs *.url *.vbe *.vbs *.vsmacros *.ws *.wsc *.wsf *.wsh) do if exist "%%b" del /f/s/q/a "%%b"
goto :nokill
:nokill
echo.
title 简易U盘病毒清理系统——安全进入U盘
echo 正在扫描删除autorun.inf...
if exist autorun.inf del /f/s/q/a autorun.inf
echo.
echo 结束资源管理器进程以消除U盘右键添加项...
echo.
taskkill /F /im explorer.exe >nul 2>nul
echo 正在打开你的U盘...
echo.
echo 您的U盘已检测完毕!请手工结束本程序。
echo.
explorer.exe !drive!
goto theEnd
:mianyi
cls
title 简易U盘病毒清理系统——U盘免疫
echo.
echo 正在建立混淆文件夹...
echo.
if exist autorun.inf del /f/s/q/a autorun.inf
md autorun.inf
attrib +r +a +s +h autorun.inf
cd autorun.inf
md Monyer...\
echo.
echo U盘免疫成功(该免疫仅对双击进入U盘有效)
echo.
echo 点击任意键以退出!
pause
goto theEnd
:jiechu
cls
title 简易U盘病毒清理系统——免疫解除
echo.
echo 正在解除免疫...
attrib -r -a -s -h autorun.inf >nul 2>nul
cd autorun.inf >nul 2>nul
rmdir Monyer...\ >nul 2>nul
cd .. >nul 2>nul
rmdir autorun.inf >nul 2>nul
echo.
echo U盘免疫解除成功
echo.
echo 点击任意键以退出!
pause
goto theEnd
:geshi
cls
title 简易U盘病毒清理系统——U盘格式化
echo.
echo 格式化会删除掉你U盘的所有文件,如果你有需要备份的,请提前做好备份!如果确定要格式化,请继续!
echo.
set /p choice=请选择(1 =我要进行U盘格式化 2 =不格式化,返回去!):
if /i "%choice%"=="1" goto geshi1
if /i "%choice%"=="2" goto go
goto geshi
:geshi1
cls
echo.
format !drive! /q/x/y
echo.
echo 格式化完毕!点击任意键以退出!
pause
goto theEnd
:theEnd
exit